To run this notebook the following packages are required, which can be obtained form the website
    http://www.risc.jku.at/research/combinat/software/

<<Guess.m;
<<HolonomicFunctions.m;
<<Hyper.m;

HolonomicFunctions package by Christoph Koutschan, RISC-Linz, Version 1.5.1 (09.08.2011)
⟶ Type  ?HolonomicFunctions  for help

Theorem 1

a[i_Integer,j_Integer] := KroneckerDelta[i,j]+Binomial[i+j-2+mu,j]

Guess the implicit description for (Subscript[c, n,j])

We first compute some data, i.e. the values of (Subscript[c, n,j]) for 1≤j≤2n≤30.

Timing[
dim=30;data={};
Do[
matrix=Table[a[i,j],{i,n-1},{j,n}];
ns=LinSolveUniv[matrix,mu];
If[Length[ns]=!=1,Throw["NullSpace is not of Length 1."]];
vec=First[ns];
vec=Together[vec/Last[vec]];
AppendTo[data,PadRight[vec,dim]];
,{n,2,dim,2}];
]

Dimensions[data]

TableForm[Take[Take[#,4]&/@data,4]]

Now we can guess some recurrences for (Subscript[c, n,j]).

rec1=GuessMultRE[data,{f[n,j],f[n,j+1],f[n+1,j]},{n,j},9,  StartPoint ->{1,1},Constraints->j≤2n]

rec2=GuessMultRE[data,{f[n,j],f[n,j+1],f[n,j+2]},{n,j},6,  StartPoint ->{1,1},Constraints->j≤2n]

Now we transform these recurrences into operators. The Gröbner basis computation serves as a check that the two recurrences are consistent, and to ensure that the generators of the annihilating ideal for (Subscript[c, n,j]) indeed constitute a Gröbner basis.

cnj=OreGroebnerBasis[ToOrePolynomial[Join[rec1,rec2],f[n,j]]];

Support[cnj]

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

AnnihilatorSingularities[cnj,{1,1},Assumptions->mu>0]

Proof of (1a)

We show that (Subscript[c, n,2n])=1.

Timing[diag=First[FindRelation[cnj,Pattern->({a_,b_}/;2*a==b)]];]

Support[diag]

lcf=Factor[LeadingCoefficient[diag]/.j->2n]

CylindricalDecomposition[Implies[mu>0&&n≥1,lcf>0],{n,mu}]

diag1= OrePolynomialSubstitute[diag,{S[j]->1,j->2*n}];

OreReduce[diag1,ToOrePolynomial[{S[n]-1}]]

Proof of (2a)

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 1≤i<2n.

Table[Together[FunctionExpand[Sum[data[[n,j]]*a[i,j],{j,1,2n}]]],{n,1,6},{i,1,n-1}]

aij0=Annihilator[Binomial[i+j-2+mu,j],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

Support[sum2a]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i}]];]

ByteCount[sum2]

UnderTheStaircase[sum2]

Support[sum2]

Factor[LeadingCoefficient/@sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.i->i-1;
lcf2=LeadingCoefficient[sum2[[2]]]/.n->n-2;

(* This means that we can apply the first recurrence everywhere except i=1. *)
CylindricalDecomposition[Implies[mu>2&&n≥1&&2≤i<n,lcf1>0],{i,n,mu}]

(* So we have to check what happens with the leading coefficient of the second recurrence for i=1. *)
Factor[lcf2/.i->1]

(* The linear factors do not introduce singularities, so we have to look at the irrducible one. *)
irred=Last[%]

CylindricalDecomposition[Implies[mu>2&&n≥3,irred>0],{n,mu}]

Proof of (3a)

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, 2n,j])==((Subscript[b, 2n])/(Subscript[b, 2n-1]))  for all n≥1.

anj0=Annihilator[Binomial[2*n+j-2+mu,j],{S[n],S[j]}]

smnd3=DFiniteTimes[anj0,cnj];

Timing[{sum3a,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3a[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

(* The Kronecker delta that was left is added here. *)
sum3=DFinitePlus[sum3a,DFiniteSubstitute[cnj,{j->2n}]];

Support[sum3]

Factor[sum3]

We now verify that the given formula satisfies the recurrence.

quo[n_]:=(-1)^((n-1)*(n-2)/2)*2^n*Pochhammer[(mu+2n)/2,Floor[(n+1)/2]]*Pochhammer[(mu+4n+1)/2,n-1]/Pochhammer[n,n]/Pochhammer[(-mu-4n+3)/2,Floor[(n-1)/2]];

(* A numerical test for the first values *)
With[{test=ApplyOreOperator[First[sum3],f[n]]},
Together[Table[test,{n,5}]/.f->quo]]

(* Symbolic simplification by case distinction n mod 4. *)
test=ApplyOreOperator[First[sum3],f[n]];
Table[FullSimplify[test/.n->4k+i/.f[kk_]:>FullSimplify[quo[kk],Element[k,Integers]]],{i,0,3}]

We can even find the closed form for the quotient:

Hyper[ApplyOreOperator[First[rec],f[n]],f[n],Solutions->All]

Theorems 2, 3, and 4

a[i_Integer,j_Integer,mu_]:=Together[-KroneckerDelta[i,j]+FunctionExpand[Binomial[mu+i+j-2,j]]];
myDet01[0]=1;
myDet01[n_]:=myDet01[n]=Together[Det[Table[-KroneckerDelta[i-1,j]+FunctionExpand[Binomial[(i-1)+j+mu-2,j]],{i,n},{j,n}]]];
myDet10[0]=1;
myDet10[n_]:=myDet10[n]=Together[Det[Table[-KroneckerDelta[i,j-1]+FunctionExpand[Binomial[i+(j-1)+mu-2,j-1]],{i,n},{j,n}]]];

(Subscript[b, 2n-1])(0,1)

Here are the first values for (Subscript[c, n,j]):

cdata={{1,0,0,0,0,0},{(mu*(1+mu))/12,(-1-mu)/2,1,0,0,0},{-(mu*(1+mu)*(2+mu)*(3+mu))/(120*(6+mu)),-(mu*(1+mu)*(2+mu)*(3+mu))/(120*(6+mu)),((2+mu)*(3+mu)*(5+mu))/(10*(6+mu)),(-3-mu)/2,1,0}};
TraditionalForm[TableForm[Table[c[n,j]==cdata[[n,j]],{n,3},{j,2n-1}]]]

(* Test (2a) *)
Together[Table[Sum[cdata[[n,j]]*a[i-1,j,mu],{j,1,2n-1}],{n,1,3},{i,1,2n-2}]]

(* Test (3a) *)
Together[Table[Sum[cdata[[n,j]]*a[(2n-1)-1,j,mu],{j,1,2n-1}]-myDet01[2n-1]/myDet01[2n-2],{n,1,3}]]

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb01odd.m";

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

(* We cannot apply these recurrences if (n,j) = (1,1), (1,2), (2,2) or if j=2n-2. *)
AnnihilatorSingularities[cnj,{1,1},Assumptions->mu>0]

Proof of (1a)

We show that (Subscript[c, n,2n-1])=1.

Timing[diag=First[FindRelation[cnj,Pattern->({a_,b_}/;2*a==b)]];]

Support[diag]

lcf=Factor[LeadingCoefficient[diag]/.j->2n-2]

(* Thus we can use the diagonal recurrence to compute the values for c(n,2n-2). *)
CylindricalDecomposition[Implies[mu>2&&n≥1,lcf>0],{n,mu}]

diag1= OrePolynomialSubstitute[diag,{S[j]->1,j->2n-1}];

OreReduce[diag1,ToOrePolynomial[{S[n]-1}]]

CylindricalDecomposition[Implies[mu>2&&n≥1,LeadingCoefficient[diag1]>0],{n,mu}]

Proof of (2a)

We show that (∑_(j=1)^(2 n-1))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 1≤i<2n-1.

aij0=Annihilator[Binomial[(i-1)+j-2+mu,j],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i-1}]];]

ByteCount[sum2]

Support[sum2]

Factor[LeadingCoefficient/@sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.i->i-1;
lcf2=LeadingCoefficient[sum2[[2]]]/.n->n-2;

(* This means that we can apply the first recurrence for i ≥ 3. *)
CylindricalDecomposition[Implies[mu>2&&n≥1&&3≤i≤2n-2,lcf1>0],{i,n,mu}]

(* So we have to check what happens with the leading coefficient of the second recurrence for i=1,2. *)
Table[CylindricalDecomposition[Implies[mu>2&&n≥3,(lcf2/.i->ii)<0],{n,mu}],{ii,1,2}]

Proof of (3a)

We show that (∑_(j=1)^(2 n-1))(Subscript[c, n,j]) (Subscript[a, 2n-1,j])==(((Subscript[b, 2n-1])(0,1))/((Subscript[b, 2n-2])(0,1)))  for all n≥1.

anj0=Annihilator[Binomial[((2n-1)-1)+j-2+mu,j],{S[n],S[j]}]

smnd3=DFiniteTimes[anj0,cnj];

Timing[{sum3a,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3a[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

(* The Kronecker delta that was left is added here. *)
sum3=DFinitePlus[sum3a,DFiniteSubstitute[cnj,{j->2n-2}]];

Support[sum3]

Factor[rec01odd=First[sum3]]

CylindricalDecomposition[Implies[mu>2&&n≥1,LeadingCoefficient[rec01odd]>0],{n,mu}]

We can even find the closed form for the quotient:

Hyper[ApplyOreOperator[rec01odd,f[n]],f[n],Solutions->All]

basis=RSolve[{y[n+1]==#*y[n],y[0]==1},y[n],n][[1,1,2]]&/@%

inits=Factor[Table[Together[myDet01[2n-1]/myDet01[2n-2]],{n,2}]]

sol01odd=Simplify[({c1,c2}/.First[Solve[Thread[Table[basis.{c1,c2},{n,2}]==inits],{c1,c2}]]).basis]

FullSimplify[sol01odd]

Table[Together[FunctionExpand[sol01odd]-myDet01[2n-1]/myDet[2n-2]],{n,5}]

(Subscript[b, 2n-1])(1,0)

cdata={{1,0,0,0,0,0},{-mu,-mu/2,1,0,0,0},{(mu*(2+mu)*(5+mu))/(2*(6+mu)),(mu*(2+mu)*(5+mu))/(4*(6+mu)),((2+mu)*(-24+mu+mu^2))/(12*(6+mu)),(-2-mu)/2,1,0}};
TraditionalForm[TableForm[Table[c[n,j]==cdata[[n,j]],{n,3},{j,2n-1}]]]

(* Test (2a) *)
Together[Table[Sum[cdata[[n,j]]*a[i,j-1,mu],{j,1,2n-1}],{n,1,3},{i,1,2n-2}]]

(* Test (3a) *)
Together[Table[Sum[cdata[[n,j]]*a[2n-1,j-1,mu],{j,1,2n-1}]-myDet10[2n-1]/myDet10[2n-2],{n,1,3}]]

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb10odd.m";

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

(* We cannot apply these recurrences if (n,j) = (1,1), (1,2), (2,2). *)
AnnihilatorSingularities[cnj,{1,1},Assumptions->mu>0]

Proof of (1a)

We show that (Subscript[c, n,2n-1])=1.

Timing[diag=First[FindRelation[cnj,Pattern->({a_,b_}/;2*a==b)]];]

Support[diag]

diag1= OrePolynomialSubstitute[diag,{S[j]->1,j->2n-1}];

OreReduce[diag1,ToOrePolynomial[{S[n]-1}]]

CylindricalDecomposition[Implies[mu>0&&n≥1,LeadingCoefficient[diag1]>0],{n,mu}]

Proof of (2a)

We show that (∑_(j=1)^(2 n-1))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 1≤i<2n-1.

aij0=Annihilator[Binomial[i+(j-1)-2+mu,j-1],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i+1}]];]

ByteCount[sum2]

Support[sum2]

Factor[LeadingCoefficient/@sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.i->i-1;
lcf2=LeadingCoefficient[sum2[[2]]]/.n->n-2;

(* This means that we can apply the first recurrence for i ≥ 2. *)
CylindricalDecomposition[Implies[mu>2&&n≥1&&2≤i≤2n-2,lcf1>0],{i,n,mu}]

(* So we have to check what happens with the leading coefficient of the second recurrence for i=1. *)
CylindricalDecomposition[Implies[mu>2&&n≥3,(lcf2/.i->1)<0],{n,mu}]

Proof of (3a)

We show that (∑_(j=1)^(2 n-1))(Subscript[c, n,j]) (Subscript[a, 2n-1,j])==(((Subscript[b, 2n-1])(1,0))/((Subscript[b, 2n-2])(1,0)))  for all n≥1.

anj0=Annihilator[Binomial[(2n-1)+(j-1)-2+mu,j-1],{S[n],S[j]}]

smnd3=DFiniteTimes[anj0,cnj];

Timing[{sum3a,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3a[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

(* The Kronecker delta that was left is added here. *)
sum3=DFinitePlus[sum3a,DFiniteSubstitute[cnj,{j->2n}]];

Support[sum3]

Factor[rec10odd=First[sum3]]

CylindricalDecomposition[Implies[mu>2&&n≥1,LeadingCoefficient[rec10odd]>0],{n,mu}]

We can even find the closed form for the quotient:

sol10odd=(64/27)^(1-n)*Pochhammer[(mu+4n-2)/2,n-1]*Pochhammer[mu/3,n-1]*Pochhammer[(mu+1)/3,n-1]*Pochhammer[(mu+2)/3,n-1]/(Pochhammer[1/2,n-1]*Pochhammer[(mu+1)/2,n-1]*Pochhammer[(mu+2)/4,n-1]*Pochhammer[mu/4,n-1])

FullSimplify[ApplyOreOperator[rec10odd,sol10odd]]

OreReduce[rec10odd,Annihilator[sol10odd,S[n]]]

Table[Together[FunctionExpand[sol10odd]-myDet10[2n-1]/myDet10[2n-2]],{n,5}]

(Subscript[b, 2n])(0,1)

Here are the first values for (Subscript[c, n,j]):

cdata={{-mu/2,1,0,0,0,0},{0,((1+mu)*(2+mu))/12,(-2-mu)/2,1,0,0},{0,-((1+mu)*(2+mu)*(3+mu)*(4+mu))/(180*(5+mu)),-((1+mu)*(2+mu)*(3+mu)*(4+mu))/(120*(5+mu)),((3+mu)*(4+mu)*(13+3*mu))/(30*(5+mu)),(-4-mu)/2,1}};
TraditionalForm[TableForm[Table[c[n,j]==cdata[[n,j]],{n,3},{j,2n}]]]

(* Test (2a) *)
Together[Table[Sum[cdata[[n,j]]*a[i-1,j,mu],{j,1,2n}],{n,1,3},{i,1,2n-1}]]

(* Test (3a) *)
Together[Table[Sum[cdata[[n,j]]*a[2n-1,j,mu],{j,1,2n}]-myDet01[2n]/myDet01[2n-1],{n,1,3}]]

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb01even.m";

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

Support[cnj]

CylindricalDecomposition[Implies[mu>0&&n≥2&&1≤j≤2n-2,(LeadingCoefficient[cnj[[1]]]/.n->n-1)<0],{n,j,mu}]

CylindricalDecomposition[Implies[mu>0&&n≥2&&3≤j≤2n-2,(LeadingCoefficient[cnj[[2]]]/.j->j-2)<0],{n,j,mu}]

(* We cannot apply the recurrences of cnj if j=2n-1. *)
Expand[{LeadingCoefficient[cnj[[1]]]/.n->n-1,LeadingCoefficient[cnj[[2]]]/.j->j-2}/.j->2n-1]

Proof of (1a)

We show that (Subscript[c, n,2n-1])=1.

Timing[diag=First[FindRelation[cnj,Pattern->({a_,b_}/;2*a==b)]];]

Support[diag]

lcf=Factor[LeadingCoefficient[diag]/.j->2n-1]

(* Thus we can use the diagonal recurrence to compute the values for c(n,2n-2). *)
CylindricalDecomposition[Implies[mu>2&&n≥1,lcf>0],{n,mu}]

diag1= OrePolynomialSubstitute[diag,{S[j]->1,j->2n}];

OreReduce[diag1,ToOrePolynomial[{S[n]-1}]]

lcf=Factor[LeadingCoefficient[diag1]]

CylindricalDecomposition[Implies[mu>2&&n≥1,lcf>0],{n,mu}]

Proof of (2a)

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 1≤i<2n.

aij0=Annihilator[Binomial[(i-1)+j-2+mu,j],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i-1}]];]

ByteCount[sum2]

Support[sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.i->i-1;
lcf2=LeadingCoefficient[sum2[[2]]]/.n->n-2;

(* This means that we can apply the first recurrence for i=2 and i≥4. *)
part2=Last[Factor[lcf1]];
part1=Factor[Together[lcf1/part2]];
CylindricalDecomposition[Implies[mu>0&&n≥1&&4≤i<2n,part1<0],{mu,i,n}]&&
CylindricalDecomposition[Implies[mu>60&&n≥1&&4≤i<2n,part2<0],{mu,i,n}]&&
CylindricalDecomposition[Implies[mu>2&&n≥2,(lcf1/.i->2)<0],{n,mu}]

(* So we have to check what happens with the leading coefficient of the second recurrence for i=1,3. *)
Table[CylindricalDecomposition[Implies[mu>2&&n≥3,(lcf2/.i->ii)<0],{n,mu}],{ii,1,3,2}]

Proof of (3a)

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, 2n,j])==(((Subscript[b, 2n])(0,1))/((Subscript[b, 2n-1])(0,1)))  for all n≥1.

anj0=Annihilator[Binomial[(2n-1)+j-2+mu,j],{S[n],S[j]}]

smnd3=DFiniteTimes[anj0,cnj];

Timing[{sum3a,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3a[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

(* The Kronecker delta that was left is added here. *)
sum3=DFinitePlus[sum3a,DFiniteSubstitute[cnj,{j->2n-1}]];

Support[sum3]

Factor[rec01even=First[sum3]]

CylindricalDecomposition[Implies[mu>2&&n≥1,LeadingCoefficient[rec01even]>0],{n,mu}]

We can even find the closed form for the quotient:

Hyper[ApplyOreOperator[rec01even,f[n]],f[n],Solutions->All]

basis=(RSolve[{y[n+1]==#*y[n]},y[n],n][[1,1,2]]&/@%)/.C[_]->1

inits=Factor[Table[Together[myDet01[2n]/myDet01[2n-1]],{n,2}]]

sol01even=Simplify[({c1,c2}/.First[Solve[Thread[Table[basis.{c1,c2},{n,2}]==inits],{c1,c2}]]).basis]

FullSimplify[sol01even]

Table[Together[FunctionExpand[sol01even]-myDet01[2n]/myDet01[2n-1]],{n,5}]

(Subscript[b, 2n])(1,0)

cdata={{1-mu,1,0,0,0,0},{((-1+mu)*(1+mu)*(6+mu))/12,(-1-mu)/2,(-1-mu)/2,1,0,0},{-((-1+mu)*(1+mu)*(3+mu)*(10+mu)*(12+mu))/720,((1+mu)*(3+mu))/6,((1+mu)*(3+mu))/6,((-2+mu)*(3+mu))/12,(-3-mu)/2,1}};
TraditionalForm[TableForm[Table[c[n,j]==cdata[[n,j]],{n,3},{j,2n}]]]

(* Test (2a) *)
Together[Table[Sum[cdata[[n,j]]*a[i,j-1,mu],{j,1,2n}],{n,1,3},{i,1,2n-1}]]

(* Test (3a) *)
Together[Table[Sum[cdata[[n,j]]*a[2n,j-1,mu],{j,1,2n}]-myDet10[2n]/myDet10[2n-1],{n,1,3}]]

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb10even.m";

{lc1,lc2,lc3}=LeadingCoefficient/@Factor[cnj]

LeadingPowerProduct/@cnj

{lc1,lc2,lc3}=Factor[{lc1/.j->j-2,lc2/.{j->j-1,n->n-1},lc3/.n->n-2}];

(* So the first recurrence can be applied for j≥3. *)
CylindricalDecomposition[Implies[mu>2&&n≥1&&3≤j≤2n,lc1<0],{mu,n,j}]

(* For j=1 the second recurrence may be used. *)
CylindricalDecomposition[Implies[mu>3&&n≥2,(lc2/.j->1)<0],{mu,n}]

(* For j=2 the third recurrence may be used. *)
CylindricalDecomposition[Implies[mu>3&&n≥3,(lc3/.j->2)>0],{mu,n}]

Proof of (1a)

We show that (Subscript[c, n,2n])=1.

Timing[diag=First[FindRelation[cnj,Pattern->({a_,b_}/;2*a==b)]];]

Support[diag]

diag1= OrePolynomialSubstitute[diag,{S[j]->1,j->2n}];

OreReduce[diag1,ToOrePolynomial[{S[n]-1}]]

CylindricalDecomposition[Implies[mu>0&&n≥1,LeadingCoefficient[diag1]>0],{n,mu}]

Proof of (2a)

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 1≤i<2n.

aij0=Annihilator[Binomial[i+(j-1)-2+mu,j-1],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i+1}]];]

ByteCount[sum2]

Support[sum2]

Factor[LeadingCoefficient/@sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.n->n-2;
lcf2=LeadingCoefficient[sum2[[2]]]/.{i->i-1,n->n-1};
lcf3=LeadingCoefficient[sum2[[3]]]/.i->i-2;

(* This means that we can apply the first recurrence for all i≤2n-3. *)
CylindricalDecomposition[Implies[mu>2&&n≥3&&1≤i≤2n-3,lcf1>0],{i,n,mu}]

(* So we have to check what happens with the leading coefficient of the second recurrence for i=2n-2,2n-1. *)
Table[CylindricalDecomposition[Implies[mu>2&&n≥3,(lcf2/.i->2n-ii)>0],{n,mu}],{ii,1,2}]

Proof of (3a)

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, 2n,j])==(((Subscript[b, 2n])(1,0))/((Subscript[b, 2n-1])(1,0)))  for all n≥1.

anj0=Annihilator[Binomial[2n+(j-1)-2+mu,j-1],{S[n],S[j]}]

smnd3=DFiniteTimes[anj0,cnj];

Timing[{sum3,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

Support[sum3]

Factor[rec10even=First[sum3]]

CylindricalDecomposition[Implies[mu>0&&n≥1,LeadingCoefficient[rec10even]<0],{n,mu}]

We can even find the closed form for the quotient:

Hyper[ApplyOreOperator[rec10even,f[n]],f[n],Solutions->All]

basis=(RSolve[{y[n+1]==#*y[n]},y[n],n][[1,1,2]]&/@%)/.C[_]->1

inits=Factor[Table[Together[myDet10[2n]/myDet10[2n-1]],{n,2}]]

sol10even=Simplify[({c1,c2}/.First[Solve[Thread[Table[basis.{c1,c2},{n,2}]==inits],{c1,c2}]]).basis]

FullSimplify[sol10even]

Table[Together[FunctionExpand[sol10even]-myDet10[2n]/myDet10[2n-1]],{n,5}]



(Subscript[b, 2n])(0,0)=-(Subscript[b, 2n-1])(1,1)

Here are the first values for (Subscript[c, n,j]):

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb0011.m";

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

Support[cnj]

lcf1=Factor[LeadingCoefficient[cnj[[1]]]/.j->j-2];
lcf2=Factor[LeadingCoefficient[cnj[[2]]]/.{j->j-1,n->n-1}];
lcf3=Factor[LeadingCoefficient[cnj[[3]]]/.n->n-2];

(* The first recurrence can be applied j≥3. *)
CylindricalDecomposition[Implies[mu>0&&n≥1&&3≤j≤2n-1,lcf1<0],{n,j,mu}]

(* The second recurrence can be applied for j≥2. *)CylindricalDecomposition[Implies[mu>0&&n≥2&&2≤j≤2n-1,lcf2>0],{n,j,mu}]

(* The third recurrence can be applied for j≤2n-3. *)CylindricalDecomposition[Implies[mu>0&&n≥3&&0≤j≤2n-3,lcf3<0],{n,j,mu}]

The union of all these areas is the full area where we want to apply (Subscript[c, n,j]).

Proof of (1c)

We show that (Subscript[c, n,0])=1.

Timing[rec=First[DFiniteSubstitute[cnj,{j->0}]];]

Support[rec]

OreReduce[rec,ToOrePolynomial[{S[n]-1}]]

lcf=Factor[LeadingCoefficient[rec]]

Clearly, for mu>0 and n≥1, this leading coefficient never becomes 0.

Proof of (2c)

We show that (∑_(j=0)^(2 n-1))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 0<i≤2n-1.

aij0=Annihilator[Binomial[i+j-2+mu,j],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i}]];]

ByteCount[sum2]

Support[sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.n->n-2;
lcf2=LeadingCoefficient[sum2[[2]]]/.{i->i-1,n->n-1};
lcf3=LeadingCoefficient[sum2[[3]]]/.i->i-2;

(* The first recurrence can be applied for i≤2n-3. *)
CylindricalDecomposition[Implies[mu>0&&n≥3&&1≤i≤2n-3,lcf1>0],{mu,i,n}]

(* The second recurrence can be applied for 2≤i≤2n-2. *)
CylindricalDecomposition[Implies[mu>1&&n≥2&&2≤i≤2n-2,lcf2>0],{mu,i,n}]

(* The third recurrence can be applied i≥3. *)
CylindricalDecomposition[Implies[mu>1&&n≥1&&3≤i≤2n-1,lcf3<0],{mu,i,n}]

Proof of (3c)

We show that (∑_(j=0)^(2 n-1))(Subscript[c, n,j]) (Subscript[a, 0,j])==(((Subscript[b, 2n])(0,0))/((Subscript[b, 2n-1])(1,1)))  for all n≥1.

a0j=Annihilator[Binomial[j-2+mu,j],{S[n],S[j]}]

smnd3=DFiniteTimes[a0j,cnj];

Timing[{sum3a,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3a[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

(* The Kronecker delta that was left is added here, but we showed before that c_{n,0}=1. *)
sum3=DFinitePlus[sum3a,Annihilator[1,S[n]]];

sum3

This means that the sum evaluates to a constant, which is:

Together[With[{n=1},Sum[c[n,j]*a[0,j,mu],{j,0,2n-1}]]/.c[1,1]->1/(1-mu)]

(Subscript[b, 2n-1])(0,0)=0

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb00.m";

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

(* We cannot apply these recurrences if (n,j) = (1,1), (1,2), (2,1), (2,2). *)
AnnihilatorSingularities[cnj,{1,1},Assumptions->mu>0]

(* We cannot apply these recurrences if (n,j) = (1,0), (1,1), (2,1). *)
AnnihilatorSingularities[cnj,{1,0},Assumptions->mu>0]

Numerical check / initial values

eqns=ApplyOreOperator[cnj,c[n,j]];
eqns=Flatten[Table[eqns,{n,5},{j,0,2n-2}]];
csol={c[1,0]->1,c[1,1]->0,c[2,1]->-mu/2};
eqns=eqns/.csol;
csol=Join[csol,First[Solve[Thread[eqns==0],Union[Cases[eqns,c[__],Infinity]]]]];
csol=Together[csol];
TableForm[Together[Table[c[n,j],{n,3},{j,0,2n-2}]/.csol]]

Table[c[n,2n-2],{n,5}]/.csol

Table[Together[(Sum[c[n,j]*FunctionExpand[Binomial[i+j-2+mu,j]],{j,0,2n-2}]-c[n,i])/.csol],{n,5},{i,0,2n-2}]

Show that (Subscript[c, n,j]) is nontrivial

We show that (Subscript[c, n,2n-2])=1.

Timing[diag=First[FindRelation[cnj,Pattern->({a_,b_}/;2*a==b)]];]

Support[diag]

diag1= OrePolynomialSubstitute[diag,{S[j]->1,j->2n-2}];

OreReduce[diag1,ToOrePolynomial[{S[n]-1}]]

CylindricalDecomposition[Implies[mu>0&&n≥1,LeadingCoefficient[diag1]>0],{mu,n}]

Proof of the linear combination

We show that (∑_(j=0)^(2 n-2))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 0≤i≤2n-2.

aij0=Annihilator[Binomial[i+j-2+mu,j],{S[i],S[n],S[j]}]

cnj0 = ToOrePolynomial[Append[cnj,S[i]-1], OreAlgebra[aij0]];

smnd2=DFiniteTimes[aij0,cnj0];

Timing[sum2a=First[FindCreativeTelescoping[smnd2,S[j]-1]];]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[sum2a,DFiniteSubstitute[cnj0,{j->i}]];]

ByteCount[sum2]

Support[sum2]

Factor[LeadingCoefficient/@sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.i->i-1;
lcf2=LeadingCoefficient[sum2[[2]]]/.n->n-2;

(* This means that we can apply the first recurrence for i≥2. *)
CylindricalDecomposition[Implies[mu>2&&n≥1&&2≤i<n,lcf1>0],{mu,i,n}]

(* So we have to check what happens with the leading coefficient of the second recurrence for i=1. *)
CylindricalDecomposition[Implies[mu>2&&n≥3,(lcf2/.i->1)<0],{n,mu}]

Conclusion

n even

(* the formula for even n *)
evaleven=(-1)^(n/2)*2^(n*(n+2)/4)*Pochhammer[mu/2,n/2]/(n/2)!*Prod[(i!)^2/((2i)!)^2,{i,0,(n-2)/2}]*Prod[Pochhammer[(mu+6i-1)/2,(n-4i+2)/2]^2*Pochhammer[(-mu-3n+6i)/2,(n-4i)/2]^2,{i,1,Floor[n/4]}];

We simplify the quotient by hand, since Mathematica cannot do this automatically:

{quo0,quo2}=(evaleven/(evaleven/.n->n-2))/.{{n->4k},{n->4k+2}};

{quo0,quo2}=ExpandAll[{quo0,quo2}/.a_Floor:>FullSimplify[a,Element[k,Integers]]]

quo0=quo0/.Pochhammer[-1/2+3i+mu/2,1-2i+2k]->Pochhammer[-1/2+3i+mu/2,-2i+2k]*(-1/2+i+mu/2+2k)/.Pochhammer[3 i-6 k-mu/2,-2 i+2 k]:>Pochhammer[3+3 i-6 k-mu/2,-1-2 i+2 k]*FunctionExpand[Pochhammer[3 i-6 k-mu/2,-2 i+2 k]/Pochhammer[3+3 i-6 k-mu/2,-1-2 i+2 k]];
quo2=quo2/.Pochhammer[-1/2+3 i+mu/2,2-2 i+2 k]->Pochhammer[-1/2+3 i+mu/2,1-2 i+2 k]*(1/2+i+2k+mu/2)/.Pochhammer[3 i-6 k-mu/2,-2 i+2 k]:>Pochhammer[-3+3 i-6 k-mu/2,1-2 i+2 k]*FunctionExpand[Pochhammer[3 i-6 k-mu/2,-2 i+2 k]/Pochhammer[-3+3 i-6 k-mu/2,1-2 i+2 k]];

{quo0,quo2}={quo0,quo2}//.Prod[a1_*a2_,a3_]->Prod[a1,a3]*Prod[a2,a3];

{quo0,quo2}={quo0,quo2}//.Prod[a1_,{i,a2_,a3_}]/Prod[a1_,{i,a2_,a4_}]/;Expand[a3-a4]==1:>(a1/.i->a3);

{quo0,quo2}={quo0,quo2}/.Prod->Product

FullSimplify[quo0/((-sol01even*sol10even)/.n->2k),Element[k,Integers]]

FullSimplify[quo2/((-sol01even*sol10even)/.n->2k+1),Element[k,Integers]]

n odd

(* the formula for odd n *)
evalodd=(-1)^((n-1)/2)*2^((n+3)*(n+1)/4)*Pochhammer[(mu-1)/2,(n+1)/2]*Prod[i!*(i+1)!/(2i)!/(2i+2)!,{i,0,(n-1)/2}]*Prod[Pochhammer[(mu+6i-1)/2,(n-4i+1)/2]^2*Pochhammer[(-mu-3n+6i-3)/2,(n-4i+3)/2]^2,{i,1,Floor[(n+1)/4]}];

We simplify the quotient by hand, since Mathematica cannot do this automatically:

{quo1,quo3}=(evalodd/(evalodd/.n->n-2))/.{{n->4k+1},{n->4k+3}};

{quo1,quo3}=ExpandAll[{quo1,quo3}/.a_Floor:>FullSimplify[a,Element[k,Integers]]]

quo1=quo1/.Pochhammer[-1/2+3i+mu/2,1-2i+2k]->Pochhammer[-1/2+3i+mu/2,-2i+2k]*(-1/2+i+mu/2+2k)/.Pochhammer[3 i-6 k-mu/2,1-2 i+2 k]:>Pochhammer[-3+3 i-6 k-mu/2,2-2 i+2 k]*FunctionExpand[Pochhammer[3 i-6 k-mu/2,1-2 i+2 k]/Pochhammer[-3+3 i-6 k-mu/2,2-2 i+2 k]];
quo3=quo3/.Pochhammer[-1/2+3 i+mu/2,2-2 i+2 k]->Pochhammer[-1/2+3 i+mu/2,1-2 i+2 k]*(1/2+i+2k+mu/2)/.Pochhammer[-3+3 i-6 k-mu/2,2-2 i+2 k]:>Pochhammer[-6+3 i-6 k-mu/2,3-2 i+2 k]*FunctionExpand[Pochhammer[-3+3 i-6 k-mu/2,2-2 i+2 k]/Pochhammer[-6+3 i-6 k-mu/2,3-2 i+2 k]];

{quo1,quo3}={quo1,quo3}//.Prod[a1_*a2_,a3_]->Prod[a1,a3]*Prod[a2,a3];

{quo1,quo3}={quo1,quo3}//.Prod[a1_,{i,a2_,a3_}]/Prod[a1_,{i,a2_,a4_}]/;Expand[a3-a4]==1:>(a1/.i->a3);

{quo1,quo3}={quo1,quo3}/.Prod->Product

FullSimplify[quo1/((-sol01odd*sol10odd)/.n->2k+1),Element[k,Integers]]

FullSimplify[quo3/((-sol01odd*sol10odd)/.n->2k+2),Element[k,Integers]]

closed forms for the solutions and for the determinants (Subscript[b, n])(0,1) and (Subscript[b, n])(1,0)

First we simplify the expression a little bit:

sols={sol01odd/.n->n+1,sol01even,sol10odd/.n->n+1,sol10even};
sols=Simplify[FullSimplify[sols]/.Gamma[a1_]/;Not[IntegerQ[a1/.{mu->0,n->0}]]:>Sqrt[Pi]*2^(1-2*a1)*Gamma[2*a1]/Gamma[a1+1/2]];
sols=sols//.{Gamma[a1_]/Gamma[a2_]/;FullSimplify[Element[a1-a2,Integers]&&(a1-a2≥0),Element[n,Integers]&&n≥1]:>Pochhammer[a2,Expand[a1-a2]],Gamma[a1_]/Gamma[a2_]/;FullSimplify[Element[a2-a1,Integers]&&(a2-a1≥0),Element[n,Integers]&&n≥1]:>1/Pochhammer[a1,Expand[a2-a1]]}

TraditionalForm[sols]

We numerically check whether they agree with the quotients of determinants:

Table[Together[sols[[1]]-myDet01[2n+1]/myDet01[2n]],{n,1,4}]

Table[Together[sols[[2]]-myDet01[2n]/myDet01[2n-1]],{n,1,4}]

Table[Together[sols[[3]]-myDet10[2n+1]/myDet10[2n]],{n,1,4}]

Table[Together[sols[[4]]-myDet10[2n]/myDet10[2n-1]],{n,1,4}]

In the following we check the closed forms numerically:

Do[Q[i][n_]:=Evaluate[sols[[i]]],{i,4}]

Table[Together[(mu-1)*Product[Q[1][k]*Q[2][k],{k,1,(n-1)/2}]-myDet01[n]],{n,1,9,2}]

Table[Together[Product[Q[1][k],{k,0,n/2-1}]*Product[Q[2][k],{k,1,n/2}]-myDet01[n]],{n,2,10,2}]

Table[Together[Product[Q[3][k]*Q[4][k],{k,1,(n-1)/2}]-myDet10[n]],{n,1,9,2}]

Table[Together[Product[Q[3][k],{k,0,n/2-1}]*Product[Q[4][k],{k,1,n/2}]-myDet10[n]],{n,2,10,2}]

Theorem 5

a[i_Integer,j_Integer,mu_]:=Together[-KroneckerDelta[i,j]+FunctionExpand[Binomial[mu+i+j-2,j]]];

Here are the first values for (Subscript[c, n,j]):

cdata={{1,(-2*(1+mu))/(mu*(3+mu)),0,0,0,0},{1,((1+mu)*(-24-mu+mu^2))/(3*mu*(3+mu)*(5+mu)),(-2*(2+mu))/(mu*(5+mu)),4/(mu*(5+mu)),0,0},{1,(2*(1+mu)*(-1620-381*mu+61*mu^2+19*mu^3+mu^4))/(5*mu*(3+mu)*(5+mu)*(7+mu)*(12+mu)),((2+mu)*(-1620-301*mu+mu^3))/(10*mu*(5+mu)*(7+mu)*(12+mu)),(-6*(-20+79*mu+20*mu^2+mu^3))/(5*mu*(5+mu)*(7+mu)*(12+mu)),(6*(4+mu)*(15+mu))/(mu*(3+mu)*(7+mu)*(12+mu)),(-12*(15+mu))/(mu*(3+mu)*(7+mu)*(12+mu))}};
TraditionalForm[TableForm[Table[c[n,j]==cdata[[n,j]],{n,3},{j,2n}]]]

In this case we have to prove slight variations of formulas 1c, 2c, and 3c:

Table[Together[Sum[cdata[[n,j]]*a[i,j,mu],{j,1,2n}]],{n,3},{i,2,2n}]

Table[Together[Sum[cdata[[n,j]]*a[1,j,mu],{j,1,2n}]],{n,3}]

Table[Together[Det[Table[a[i,j,mu],{i,1,2n},{j,1,2n}]]/Det[Table[a[i,j,mu],{i,2,2n},{j,2,2n}]]],{n,3}]

We load the guessed recurrences for (Subscript[c, n,j]):

cnj=<<"gb1122.m";

LeadingCoefficient/@Factor[cnj]

UnderTheStaircase[cnj]

Support[cnj]

lcf1=Factor[LeadingCoefficient[cnj[[1]]]/.n->n-2];
lcf2=Factor[LeadingCoefficient[cnj[[2]]]/.j->j-3];
lcf3=Factor[LeadingCoefficient[cnj[[3]]]/.{j->j-2,n->n-1}];

(* The second recurrence can be applied for j≥4. *)
CylindricalDecomposition[Implies[mu>0&&n≥1&&4≤j≤2n,lcf2<0],{n,j,mu}]

(* The first recurrence can be applied for j≤2n-6. *)
CylindricalDecomposition[Implies[mu>0&&n≥1&&1≤j≤2n-6,lcf1>0],{n,j,mu}]

(* The third recurrence can be applied for 3≤j≤2n-2. *)CylindricalDecomposition[Implies[mu>0&&n≥1&&3≤j≤2n-2,lcf3>0],{n,j,mu}]

The union of all these areas is the full area where we want to apply (Subscript[c, n,j]).

Proof of (1c')

We show that (Subscript[c, n,1])=1.

Timing[rec=First[DFiniteSubstitute[cnj,{j->1}]];]

Support[rec]

OreReduce[rec,ToOrePolynomial[{S[n]-1}]]

lcf=Factor[LeadingCoefficient[rec]]

Clearly, for mu>0 and n≥1, this leading coefficient never becomes 0.

Proof of (2c')

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, i,j])==0  for all 1<i≤2n.

aij0=Annihilator[Binomial[i+j-2+mu,j],{S[n],S[j],S[i]}];

cnj0=ToOrePolynomial[Prepend[cnj,S[i]-1],OreAlgebra[aij0]];

smnd2=Together[DFiniteTimes[aij0,cnj0]];

{sum2a,delta2a}=<<"conj36_2c_ct.m";

MapThread[Timing[OreReduce[#1+(S[j]-1)**#2,smnd2]]&,{sum2a,delta2a}]

(* The Kronecker delta that was left is added here. *)
Timing[sum2=DFinitePlus[Expand[sum2a],DFiniteSubstitute[cnj0,{j->i}]];]

Support[sum2]

lcf1=LeadingCoefficient[sum2[[1]]]/.n->n-2;
lcf2=LeadingCoefficient[sum2[[2]]]/.i->i-3;
lcf3=LeadingCoefficient[sum2[[3]]]/.{i->i-2,n->n-1};

(* This means that we can apply the first recurrence for i ≤ 2n-6. *)
CylindricalDecomposition[Implies[mu>50&&n≥3&&1≤i≤2n-6,lcf1<0],{mu,i,n}]

(* This means that we can apply the second recurrence for i ≥ 4. *)
CylindricalDecomposition[Implies[mu>0&&n≥1&&4≤i≤2n,lcf2<0],{mu,i,n}]

(* This means that we can apply the second recurrence for 3 ≤ i ≤ 2n-2. *)
CylindricalDecomposition[Implies[mu>0&&n≥1&&3≤i≤2n-2,lcf3<0],{mu,i,n}]

Proof of (3c')

We show that (∑_(j=1)^(2 n))(Subscript[c, n,j]) (Subscript[a, 1,j])==(((Subscript[b, 2n])(1,1,mu-2))/((Subscript[b, 2n-1])(2,2,mu-2)))  for all n≥1.

a1j=Annihilator[Binomial[1+j-2+mu,j],{S[n],S[j]}]

smnd3=DFiniteTimes[a1j,cnj];

Timing[{sum3a,certificate} =FindCreativeTelescoping[smnd3,S[j]-1];]

(* We cross-check the correctness of the previous output. *)
Timing[OreReduce[sum3a[[1]]+(S[j]-1)**certificate[[1,1]],Together[smnd3]]]

(* The Kronecker delta that was left is added here, but we showed before that c_{n,1}=1. *)
sum3=DFinitePlus[sum3a,Annihilator[1,S[n]]];

(* This means that sum3 evaluates to a constant. *)
sum3

(* the formula for b_{2n}(1,1,mu), copied from Thm 2. *)
eval11=(-1)^(n/2)*2^(n*(n+2)/4)*Pochhammer[mu/2,n/2]/(n/2)!*Prod[(i!)^2/((2i)!)^2,{i,0,(n-2)/2}]*Prod[Pochhammer[(mu+6i-1)/2,(n-4i+2)/2]^2*Pochhammer[(-mu-3n+6i)/2,(n-4i)/2]^2,{i,1,Floor[n/4]}];

(* the formula for b_{2n-1}(2,2,mu-2) *)
eval22=(-1)^((n-1)/2)*2^((n-1)(n+5)/4)*(mu+1)*Pochhammer[(mu-2)/2,(n+1)/2]/((n+1)/2)!*Prod[(i!)^2/((2i)!)^2,{i,0,(n-1)/2}]*Prod[Pochhammer[(mu+6i-3)/2,(n-4i+3)/2]^2,{i,1,Floor[(n+3)/4]}]*Prod[Pochhammer[(-mu-3n+6i-1)/2,(n-4i+1)/2]^2,{i,1,Floor[(n+1)/4]}];

(* In order to evaluate the quotient symbolically, we make a case distinction *)
quo=(eval11/.n->2n)/(eval22/.mu->mu+2/.n->2n-1);
{quo0,quo1}=ExpandAll[quo/.{{n->2k},{n->2k-1}}/.a_Floor:>FullSimplify[a,Element[k,Integers]]];

quo0=quo0/.With[{a1=Pochhammer[3+3 i-6 k-mu/2,-2-2 i+2 k],a2=Pochhammer[3 i-6 k-mu/2,-2 i+2 k]},a1:>a2*FunctionExpand[a1/a2]]/.With[{a1=Pochhammer[-1/2+3 i+mu/2,1-2 i+2 k],a2=Pochhammer[5/2+3 i+mu/2,-1-2 i+2 k]},a1:>a2*FunctionExpand[a1/a2]];

quo1=quo1/.With[{a1=Pochhammer[3+3 i-6 k-mu/2,-1-2 i+2 k],a2=Pochhammer[6+3 i-6 k-mu/2,-3-2 i+2 k]},a1:>a2*FunctionExpand[a1/a2]]/.With[{a1=Pochhammer[-1/2+3 i+mu/2,-2 i+2 k],a2=Pochhammer[5/2+3 i+mu/2,-2-2 i+2 k]},a1:>a2*FunctionExpand[a1/a2]];

{quo0,quo1}=Factor[{quo0,quo1}]//.Prod[a1_*a2_,a3_]->Prod[a1,a3]*Prod[a2,a3]//.Prod[a1_,{i,1,k-1}]/Prod[a1_,{i,1,k}]:>(1/a1/.i->k)

{quo0,quo1}=Factor[{quo0,quo1}/.Prod->Product]

(* some initial values *)
Factor[Table[Det[Table[-KroneckerDelta[i,j]+FunctionExpand[Binomial[mu+i+j-2,j]],{i,n},{j,n}]],{n,2,8,2}]/Table[Det[Table[-KroneckerDelta[i,j]+FunctionExpand[Binomial[(mu+2)+i+j-2,j+1]],{i,n},{j,n}]],{n,1,7,2}]]

Conjecture 6

Clear[myC,myE,myF,myT,myS1,myS2,myP1,myP2,myG,D34];
myC[n_Integer?Positive]:=((-1)^n+3)/2*Product[Floor[i/2]!/i!,{i,1,n}];
myE[n_Integer?Positive,mu_]:=Pochhammer[mu+1,n]*Product[(mu+2i+6)^(2*Floor[(i+2)/3]),{i,1,Floor[3/2*Floor[(n-1)/2]-2]}]*
Product[(mu+2i+2*Floor[3/2*Floor[n/2+1]]-1)^(2*Floor[Floor[n/2]/2-(i-1)/3]-1),{i,1,Floor[3/2*Floor[n/2]-2]}];
myF[m:(0|1),n_Integer?Positive,mu_]:=
Product[(mu+2i+n+m)^(1-2i-m),{i,1,Floor[(n-1)/4]}]*Product[(mu-2i+2n-2m+1)^(1-2i-m),{i,1,Floor[n/4-1]}];
myF[n_Integer?Positive,mu_]:=Which[
EvenQ[n],myE[n,mu]*myF[0,n,mu],
OddQ[n],myE[n,mu]*myF[1,n,mu]*Product[mu+2n+2i-1,{i,1,(n-5)/2}]];
myT[k_,mu_]:=-12+84*k+288*k^2-5856*k^3+20352*k^4-41472*k^5+55296*k^6+10*mu+76*k*mu-2176*k^2*mu+9888*k^3*mu-25344*k^4*mu+41472*k^5*mu+10*mu^2-261*k*mu^2+1676*k^2*mu^2-5472*k^3*mu^2+11520*k^4*mu^2-10*mu^3+115*k*mu^3-488*k^2*mu^3+1440*k^3*mu^3+2*mu^4-15*k*mu^4+76*k^2*mu^4+k*mu^5;
myS1[n_Integer?Positive,mu_]:=Sum[myT[k,mu]*2^(6k)*(mu+8 k-1)*Pochhammer[1/2,2k-1]^2*Pochhammer[(mu+4k+2)/2,2n-2k-2]*Pochhammer[(mu+5)/2,2k-3]*Pochhammer[(mu+4k+2)/2,k-2]/
((2k)!*Pochhammer[(mu+6k-3)/2,3k+4]),{k,1,n-1}];
myS2[n_Integer?Positive,mu_]:=
Sum[myT[k+1/2,mu]*2^(6k)*(mu+8 k+3)*Pochhammer[1/2,2k]^2*Pochhammer[(mu+4k+4)/2,2n-2k-2]*Pochhammer[(mu+5)/2,2k-2]*Pochhammer[(mu+4k+4)/2,k-2]/
((2k+1)!*Pochhammer[(mu+6k+1)/2,3k+5]),{k,1,n-1}];
myP1[n_Integer?Positive,mu_]:=Together[
2^(3n-1)*Pochhammer[(mu+6n-3)/2,3n-2]/Pochhammer[(mu+5)/2,2n-3]*
(2^(-13)*mu*(mu-1)*myS1[n,mu]+1/(mu+3)^2*Pochhammer[(mu+2)/2,2n-2])];
myP2[n_Integer?Positive,mu_]:=Together[
2^(3n-1)*Pochhammer[(mu+6n+1)/2,3n-1]/Pochhammer[(mu+5)/2,2n-2]*
(2^(-9)mu*(mu-1)*myS2[n,mu]+(mu+14)/((mu+7)*(mu+9))*Pochhammer[(mu+4)/2,2n-2])];
myG[n_Integer?Positive,mu_]:=If[EvenQ[n],myP2[n/2,mu],myP1[(n+1)/2,mu]];
D34[n_Integer?Positive,mu_]:=myC[n]*myF[n,mu]*myG[Floor[(n+1)/2],mu];

Table[Expand[D34[n,mu]-Det[Table[FunctionExpand[KroneckerDelta[i,j]+Binomial[i+j-2+mu,j]],{i,n},{j,n}]]],{n,10}]

Here is a faster variant to compute D34:

Clear[myGfast,D34fast,myP1fast,myP2fast];
myP1fast[1,mu_]=1;
myP1fast[2,mu_]=3432+722*mu+45*mu^2+mu^3;
myP1fast[n_Integer/;n≥3,mu_]:=myP1fast[n,mu]=Together[(-8*(-10+mu+4*n)*(-8+mu+4*n)*(-14+mu+6*n)*(-12+mu+6*n)*(-10+mu+6*n)*(-9+mu+8*n)*(-31+mu+12*n)*(-29+mu+12*n)*(-27+mu+12*n)*(-25+mu+12*n)*(-23+mu+12*n)*(-21+mu+12*n)*(81-72*n+16*n^2)*(49-56*n+16*n^2)*(123168-78946*mu+18939*mu^2-2053*mu^3+93*mu^4-mu^5+(-9+mu)*(70956-30208*mu+3989*mu^2-158*mu^3+mu^4)*n+4*(346032-149656*mu+21803*mu^2-1202*mu^3+19*mu^4)*n^2+96*(-9+mu)*(1861-402*mu+15*mu^2)*n^3+384*(2753-606*mu+30*mu^2)*n^4+41472*(-9+mu)*n^5+55296*n^6)*myP1fast[-2+n,mu]+(-13+mu+8*n)*(-6*(-15+mu)*(-11+mu)*(-9+mu)*(77272834343040-90508623095808*mu+46786094223720*mu^2-14041912717156*mu^3+2707887452266*mu^4-350541498059*mu^5+30888280625*mu^6-1838952303*mu^7+72032193*mu^8-1778033*mu^9+26555*mu^10-241*mu^11+mu^12)+(-13+mu)*(615591764176296960-787691318438414592*mu+453271146257615040*mu^2-154970921382725880*mu^3+35030740197791460*mu^4-5511255715119386*mu^5+618465455797003*mu^6-49890145667170*mu^7+2877469024970*mu^8-116576723262*mu^9+3218550024*mu^10-58094110*mu^11+655730*mu^12-4400*mu^13+13*mu^14)*n+(43790163197061415680-55769554581921674496*mu+32100807569482408752*mu^2-11046065343390418896*mu^3+2532539665806086200*mu^4-408068212472225048*mu^5+47486735062736003*mu^6-4036853597489641*mu^7+250606824181572*mu^8-11237476473228*mu^9+356071800098*mu^10-7704642502*mu^11+108621484*mu^12-941780*mu^13+4611*mu^14-9*mu^15)*n^2+2*(-13+mu)*(5765368315087296000-6423796647403130880*mu+3186986194272026736*mu^2-928737086880929008*mu^3+176577512806080224*mu^4-23002876518214396*mu^5+2097912117891133*mu^6-134465197774532*mu^7+5992468266728*mu^8-181075265324*mu^9+3560096842*mu^10-42928700*mu^11+293696*mu^12-1000*mu^13+mu^14)*n^3+8*(44967647815472773440-49875119477893931904*mu+24771543294236452512*mu^2-7277588373063623552*mu^3+1407087781066080464*mu^4-188436568279081716*mu^5+17910169812661579*mu^6-1217322600443922*mu^7+58827888448174*mu^8-1983671151898*mu^9+45113742796*mu^10-655655046*mu^11+5605730*mu^12-24666*mu^13+41*mu^14)*n^4+32*(-13+mu)*(1545137447830050528-1468846207754989056*mu+613359955784013384*mu^2-148046294338567160*mu^3+22867645137091796*mu^4-2363768523778396*mu^5+166104951524749*mu^6-7900529853234*mu^7+248588564859*mu^8-4947975304*mu^9+57722923*mu^10-345266*mu^11+785*mu^12)*n^5+128*(6923436910786740816-6551979917272781760*mu+2741775205145125620*mu^2-668624737408815316*mu^3+105402483452844020*mu^4-11258804752461004*mu^5+830334150499955*mu^6-42256983681030*mu^7+1457399275653*mu^8-32763679904*mu^9+447520681*mu^10-3258554*mu^11+9319*mu^12)*n^6+1024*(-13+mu)*(72414477952775604-57105723925009800*mu+19399742350341207*mu^2-3719307354992416*mu^3+442850412559382*mu^4-33955375237500*mu^5+1681820711178*mu^6-52507834704*mu^7+974233650*mu^8-9518828*mu^9+36355*mu^10)*n^7+4096*(204759442490425380-160746724570083012*mu+54801297077548677*mu^2-10648677530738482*mu^3+1300829127395384*mu^4-103865351431818*mu^5+5455145057379*mu^6-184594947228*mu^7+3811103508*mu^8-42749540*mu^9+194248*mu^10)*n^8+49152*(-13+mu)*(920215916156142-577914239846832*mu+151701784373213*mu^2-21614250577806*mu^3+1815722558519*mu^4-91353917016*mu^5+2663224490*mu^6-40669644*mu^7+245586*mu^8)*n^9+196608*(1693595159851230-1058822980698432*mu+279542833819585*mu^2-40572445515984*mu^3+3526446267001*mu^4-187021320840*mu^5+5872755784*mu^6-99020958*mu^7+679074*mu^8)*n^10+21233664*(-13+mu)*(550446775412-258091315032*mu+47985773125*mu^2-4496668860*mu^3+222288724*mu^4-5456352*mu^5+51547*mu^6)*n^11+28311552*(1958821138060-914306594496*mu+171668385371*mu^2-16540689390*mu^3+859090262*mu^4-22689546*mu^5+236549*mu^6)*n^12+21403533312*(-13+mu)*(57395792-17859456*mu+1964631*mu^2-89610*mu^3+1425*mu^4)*n^13+12230590464*(290157464-89880912*mu+10081119*mu^2-483594*mu^3+8337*mu^4)*n^14+3522410053632*(-13+mu)*(12823-1986*mu+69*mu^2)*n^15+3522410053632*(19340-2982*mu+111*mu^2)*n^16+380420285792256*(-13+mu)*n^17+169075682574336*n^18)*myP1fast[-1+n,mu])/((-1+n)*(-3+2*n)*(-6+mu+4*n)*(-5+mu+4*n)*(-4+mu+4*n)*(-3+mu+4*n)*(-9+mu+6*n)*(-7+mu+6*n)*(-5+mu+6*n)*(-17+mu+8*n)*(-2*(-2619750+910279*mu-117666*mu^2+6856*mu^3-168*mu^4+mu^5)+(-17+mu)*(862188-199648*mu+14213*mu^2-302*mu^3+mu^4)*n+4*(4278168-996880*mu+77747*mu^2-2282*mu^3+19*mu^4)*n^2+96*(-17+mu)*(6541-762*mu+15*mu^2)*n^3+384*(9773-1146*mu+30*mu^2)*n^4+41472*(-17+mu)*n^5+55296*n^6))];
myP2fast[1,mu_]=mu+14;
myP2fast[2,mu_]=201552+38364*mu+2552*mu^2+81*mu^3+mu^4;
myP2fast[n_Integer/;n≥3,mu_]:=myP2fast[n,mu]=Together[(-8*(-8+mu+4*n)*(-6+mu+4*n)*(-12+mu+6*n)*(-10+mu+6*n)*(-8+mu+6*n)*(-5+mu+8*n)*(-25+mu+12*n)*(-23+mu+12*n)*(-21+mu+12*n)*(-19+mu+12*n)*(-17+mu+12*n)*(-15+mu+12*n)*(49-56*n+16*n^2)*(25-40*n+16*n^2)*(-((-3+mu)*(2788-2196*mu+577*mu^2-54*mu^3+mu^4))+2*(-5+mu)*(7620-5536*mu+1253*mu^2-86*mu^3+mu^4)*n+8*(35820-26716*mu+6791*mu^2-662*mu^3+19*mu^4)*n^2+192*(-5+mu)*(601-222*mu+15*mu^2)*n^3+768*(863-336*mu+30*mu^2)*n^4+82944*(-5+mu)*n^5+110592*n^6)*myP2fast[-2+n,mu]+(-9+mu+8*n)*(-((-11+mu)*(-7+mu)*(-5+mu)*(-3+mu)*(-941137562880+1369543037568*mu-856059425680*mu^2+301467356208*mu^3-65925560840*mu^4+9300152544*mu^5-851420265*mu^6+49707939*mu^7-1788230*mu^8+38538*mu^9-505*mu^10+3*mu^11))+(-9+mu)*(2174231624313600-4271307638939136*mu+3746500640981808*mu^2-1938172937860384*mu^3+658024132807528*mu^4-154336161708664*mu^5+25631896940311*mu^6-3038647883536*mu^7+255911958856*mu^8-15059474264*mu^9+601933862*mu^10-15728672*mu^11+258008*mu^12-2528*mu^13+11*mu^14)*n-4*(-41108205131322624+79558217840920896*mu-69190984849287408*mu^2+35769692404688632*mu^3-12252335726377252*mu^4+2933722316842738*mu^5-504752475079572*mu^6+63145862893203*mu^7-5745369671196*mu^8+376356342416*mu^9-17384266580*mu^10+548066954*mu^11-11274720*mu^12+143142*mu^13-1032*mu^14+3*mu^15)*n^2+4*(-9+mu)*(23845345590072960-40269695568954624*mu+30117142128190992*mu^2-13158415762916400*mu^3+3730778330679232*mu^4-721067843021868*mu^5+97108500711985*mu^6-9153045269192*mu^7+597928404668*mu^8-26432573136*mu^9+759984806*mu^10-13416552*mu^11+134684*mu^12-676*mu^13+mu^14)*n^3+16*(195243602402676096-325694901477820032*mu+242221596032134128*mu^2-106098978486724128*mu^3+30459989915673992*mu^4-6033975669037412*mu^5+845417566861997*mu^6-84452424919988*mu^7+5983741160080*mu^8-295319349276*mu^9+9821158066*mu^10-208695676*mu^11+2610160*mu^12-16816*mu^13+41*mu^14)*n^4+64*(-9+mu)*(14622810947299008-20883005872697088*mu+13042640269010160*mu^2-4687978533249048*mu^3+1073821472622084*mu^4-163965505744412*mu^5+16961587465549*mu^6-1184203363074*mu^7+54575767659*mu^8-1588856808*mu^9+27087171*mu^10-236578*mu^11+785*mu^12)*n^5+256*(68159047060299744-96275531839385520*mu+59912949582646848*mu^2-21651596638546640*mu^3+5041402403618604*mu^4-793018597591700*mu^5+85896040596299*mu^6-6405365947182*mu^7+323083532589*mu^8-10605978520*mu^9+211271829*mu^10-2240614*mu^11+9319*mu^12)*n^6+2048*(-9+mu)*(1541341241341668-1813373921002968*mu+915446118884163*mu^2-259814716685092*mu^3+45629241741242*mu^4-5143009129752*mu^5+373337413062*mu^6-17038328436*mu^7+461072406*mu^8-6556280*mu^9+36355*mu^10)*n^7+8192*(4500207031276008-5239264901634576*mu+2640189965261667*mu^2-755987780804488*mu^3+135697154047598*mu^4-15878627119200*mu^5+1219280284095*mu^6-60190646760*mu^7+1809241320*mu^8-29487896*mu^9+194248*mu^10)*n^8+98304*(-9+mu)*(43421763841182-40431075715248*mu+15676365711905*mu^2-3287037266982*mu^3+404944404503*mu^4-29779385976*mu^5+1265065310*mu^6-28070508*mu^7+245586*mu^8)*n^9+393216*(81960492523446-75530247171240*mu+29304166747543*mu^2-6232480720254*mu^3+791707261321*mu^4-61212289536*mu^5+2795677186*mu^6-68402040*mu^7+679074*mu^8)*n^10+42467328*(-9+mu)*(56814548324-39259013448*mu+10716187369*mu^2-1468655040*mu^3+105783400*mu^4-3770148*mu^5+51547*mu^6)*n^11+56623104*(206001269260-140889461280*mu+38650036817*mu^2-5426533428*mu^3+409650908*mu^4-15687096*mu^5+236549*mu^6)*n^12+42807066624*(-9+mu)*(12790352-5830560*mu+935607*mu^2-61962*mu^3+1425*mu^4)*n^13+24461180928*(65459144-29536992*mu+4812879*mu^2-334554*mu^3+8337*mu^4)*n^14+7044820107264*(-9+mu)*(6091-1374*mu+69*mu^2)*n^15+7044820107264*(9242-2064*mu+111*mu^2)*n^16+760840571584512*(-9+mu)*n^17+338151365148672*n^18)*myP2fast[-1+n,mu])/((-1+n)*(-1+2*n)*(-4+mu+4*n)*(-3+mu+4*n)*(-2+mu+4*n)*(-1+mu+4*n)*(-5+mu+6*n)*(-3+mu+6*n)*(-1+mu+6*n)*(-13+mu+8*n)*(2136180-963208*mu+161921*mu^2-12281*mu^3+391*mu^4-3*mu^5+2*(-13+mu)*(298788-89728*mu+8309*mu^2-230*mu^3+mu^4)*n+8*(1475028-447124*mu+45455*mu^2-1742*mu^3+19*mu^4)*n^2+192*(-13+mu)*(3841-582*mu+15*mu^2)*n^3+768*(5723-876*mu+30*mu^2)*n^4+82944*(-13+mu)*n^5+110592*n^6))];
myGfast[n_Integer?Positive,mu_]:=If[EvenQ[n],myP2fast[n/2,mu],myP1fast[(n+1)/2,mu]];
D34fast[n_Integer?Positive,mu_]:=myC[n]*myF[n,mu]*myGfast[Floor[(n+1)/2],mu];

First/@{Timing[Table[D34[n,mu],{n,100}];],Timing[Table[D34fast[n,mu],{n,100}];]}

Conjecture 37 of (Krattenthaler 2005)

det37[n_,r_]:=Together[Det[Table[-KroneckerDelta[i,j+r-1]+FunctionExpand[Binomial[mu+i+j-2,j+r-1]],{i,n},{j,n}]]];
eval37[n_,r_]:=(-1)^((n-r)/2)*2^((n^2+6n-2n r+r^2-4r+2)/4)*Product[i!,{i,0,r-2}]*Product[((n-2i-2)!)^2/(((n-2i-3)/2)!)^2/(n+2i)!/(n+2i+2)!,{i,0,(r-3)/2}]*(mu-r)*Pochhammer[(mu+1)/2,(n-r)/2]*Product[Pochhammer[mu-r+i,n+r-2i+1],{i,1,r-1}]*Product[i!*(i+1)!/(2i)!/(2i+2)!,{i,0,(n-1)/2}]*Product[Pochhammer[mu/2+3i+r+3/2,(n-4i-r-2)/2]^2*Pochhammer[-mu/2-3n/2+r/2+3i+1,(n-4i-r)/2]^2,{i,0,Floor[(n-r-2)/4]}]

Table[Together[det37[n,r]-eval37[n,r]],{n,1,7,2},{r,1,n,2}]

FullSimplify[Together[det37[3,2]-eval37[3,2]]]

Together[det37[3,5]-eval37[3,5]]